*comment game
In the Old Cathedral, the saintess raises a chalice at the altar as the congregation weeps for the Hero of Sienan. What is the name gracing their lips?
*input_text fname
*set nameset true

In a small town in the Parami east, the innkeep's lips tremble as she plants flowers around a pair of graves. Whose names are etched onto the headstones?
*choice
    #The innkeep's two sons.
        *set they "he"
        *set their "his"
        *set them "him"
        *set themselves "himself"
        *set theirs "his"
        *set pronvar 1
        *set plural false
        *set gender "male"
    #A daughter, and a son.
        *set they "she"
        *set their "her"
        *set them "her"
        *set themselves "herself"
        *set theirs "hers"
        *set pronvar 2
        *set plural false
        *set gender "female"
    #A son, and someone who eschewed such labels.
        *set they "they"
        *set their "their"
        *set them "them"
        *set themselves "themselves"
        *set theirs "theirs"
        *set pronvar 3
        *set plural true
        *set gender "nonbinary"

*set genderset true
Beside her shaking form stands another, a lone visitor come to pay their respects. What words have they for the innkeep?
*choice
    #"Sorry Sofiya can't make it, Aunt Bess. She hasn't stopped crying since she heard the news."
        *set charisma true
    #"$!{they} always @{plural were|was} a kind soul, Bess. I still have the books ${they} gave me when ${they} left."
        *set learning true
    #"It's a shame...${they} @{plural were|was} a damn good informant. My very best."
        *set intrigue true

In a city to the far west, Saint Augur's blade is raised for the knighting of a new paladin. Whose name is ordained by the Commander?
*choice
    #Elias Revelois.
        *set geli "male"
        *set elias "Elias"
        *set ehe "he"
        *set ehim "him"
        *set ehis "his"
        *set etheirs "his"
        *set ehes "he's"
        *set evar 1
    #Eliana Revelois.
        *set geli "female"
        *set elias "Eliana"
        *set ehe "she"
        *set ehim "her"
        *set ehis "her"
        *set etheirs "hers"
        *set ehes "she's"
        *set evar 2

In a paradise in the sky, a pair of assassins murmur in awe of their two commanders. Whose names grace their lips?
*choice
    #Yusuha and Falco Mateus.
        *set gfalco "male"
        *set fhe "he"
        *set fhim "him"
        *set fhis "his"
        *set ftheirs "his"
        *set fhes "he's"
        *set fvar 1
        *set falco "Falco"
        *set gyusuha "male"
        *set yhe "he"
        *set yhim "him"
        *set yhis "his"
        *set ytheirs "his"
        *set yhes "he's"
        *set yvar 1
        *set yusuha "Yusuha"
    #Yurui and Flyss Mateus.
        *set gyusuha "female"
        *set yhe "she"
        *set yhim "her"
        *set yhis "her"
        *set ytheirs "hers"
        *set yhes "she's"
        *set yvar 2
        *set yusuha "Yurui"
        *set gfalco "female"
        *set fhe "she"
        *set fhim "her"
        *set fhis "her"
        *set ftheirs "hers"
        *set fhes "she's"
        *set fvar 2
        *set falco "Flyss"
    #Yusuha and Flyss Mateus.
        *set gyusuha "male"
        *set yhe "he"
        *set yhim "him"
        *set yhis "his"
        *set ytheirs "his"
        *set yhes "he's"
        *set yvar 1
        *set yusuha "Yusuha"
        *set gfalco "female"
        *set fhe "she"
        *set fhim "her"
        *set fhis "her"
        *set ftheirs "hers"
        *set fhes "she's"
        *set fvar 2
        *set falco "Flyss"
    #Yurui and Falco Mateus.
        *set gyusuha "female"
        *set yhe "she"
        *set yhim "her"
        *set yhis "her"
        *set ytheirs "hers"
        *set yhes "she's"
        *set yvar 2
        *set yusuha "Yurui"
        *set gfalco "male"
        *set fhe "he"
        *set fhim "him"
        *set fhis "his"
        *set ftheirs "his"
        *set fhes "he's"
        *set fvar 1
        *set falco "Falco"

The stage is set, and the pyre lit. But before the archmage fell from grace, to be murdered at the hands of those ${they}'d served, one person scoured the whole of Arvanand in search of ${them}. This is ${ehis} story.

*page_break

The traveler wakes up a miserable, shivering mess, the cold air clinging to ${ehis} bones like the jaws of a starved wolf. Were ${ehe} a believer of the old gods—Thustusa on his flaming steed, or Dai who charted the night sky—then ${ehe}'d be convinced that barren, frigid Noringia is the domain of Morana herself. It's difficult to believe that anyone had seen this frozen wasteland and deemed it a good place to put down roots. That enough people thought so for a functional hamlet—dare ${ehe} say, a [i]town[/i]—to manifest itself upon the beds of age-old snow is frankly preposterous.

And yet here ${ehe} is, in the gaping maw of this ice-white beast. And ${ehe} only has Moira to blame for it.

It's not like ${ehe} doesn't understand why the woman's chosen Noringia as her base of operations. A person of her trade has need for inconspicuous domains—better still if said domain is hostile to foreign informants. With these criteria in mind, it's a wonder that Noringia isn't home to [i]all[/i] the netters in Arvanand.

Still, as ${ehe} eyes the woman across the room, it's difficult not to resent Moira for not sharing in ${ehis} misery. She soaks up the morning sunlight as if she were a flowering plant, entirely unfazed by the cold air kissing her bare skin. She is a tall woman—statuesque, even—but she appears weightless as she slinks across the room. The blanket is draped around her shoulder like a makeshift coat, its other end trailing behind her through the dusty floor. $!{ehe}'d have had a reprimand for that, normally, but ${ehe}'s not sure ${ehis} chattering teeth would lend it the intended effect.

A cold draft blows through the room as the woman throws the window open, and then—seemingly out of thin air—a pure-white pigeon materializes from the snow-streaked air.The traveler spies the parchment attached to its leg and immediately sits up, all the ache and drowsiness promptly leaving ${ehis} body. $!{ehe} has one foot on the ground and a heart thundering in ${ehis} chest, but is stopped in ${ehis} tracks as the woman reads the letter aloud.

[i]Madam,[/i]

[i]It's not good news. No one reliable can confirm the nightingale anywhere along the border. We suspect @{pronvar he's|she's|they've} flown east to foreign coasts, or further south into the old realms. Two whispers point to the southeast, well past deep verdure—an unlikely lead, but one we will look into all the same. We've dispatched a man to contact the nearby netter, and we expect to hear back from him within the fortnight.[/i]

[i]The bulk of our resources will be sent to the old realms. We have strong leverage in this region, and will spare no expense in our search. If our nightingale is anywhere around Kantena, and as powerful as you say ${they} @{plural are|is}, we will sniff ${them} out.[/i]

[i]Pray await further news. We will send word again soon.[/i]

*page_break

The woman is impassive as she stalks to the fireplace and feeds her letter to the blaze. The firelight dances in her eyes, red streaks against midnight black, and she watches in silence as it burns to ashes. "There you have it," she grouses, her displeasure palpable. "Yotai, the Old Nobles' lands, even Jove-forsaken Esteram…we've not narrowed things down much more than when we began. This ${fname} of yours continues to prove quite the slippery one."

"Sounds like ${them}," the healer replies, vaguely aware of the wry fondness creeping into ${ehis} tone. The woman eyes ${ehim} with something like disdain—though ${ehe} guesses it's less for ${ehis} sentiment, and more for the fact that she's exchanging words with a sentient bundle of blankets.
*if (charisma)
    "$!{they} could always talk ${themselves} out of a corner, no matter how dire things might seem. If anyone could make your people lose ${their} trail, it'd be ${them}."
    
    "Aren't you rooting for ${them} a mite too much in this situation?" the woman chides. "You're the one that wants to find ${them}, Eli."
    
    "Old habits die hard," ${ehe} confesses. "And it bodes well for ${their} odds against…${their} other pursuer."
    
    "You've mentioned that a couple of times," the woman leads, the lilt of curiosity expertly masked. $!{ehe} does not need to hear it to know she's prying, as she's prone to do these days.
    
    "Mm," is the response ${ehe} settles on. $!{ehe} trusts Moira, but it would be poor wisdom to divulge more information than is strictly necessary for her operation to run. "So the search goes on."
    *goto nextmoi
*elseif (learning)
    "@{pronvar He'd|She'd|They'd} hardly ever been out of Salantira City before, but if anyone could find their way around Arvanand in spite of that, it'd be ${them}."
    
    "You've so much faith in ${them}, Eli," the woman muses. "$!{they} must be quite the character."
    
    "Mm," is the response ${ehe} settles on. $!{ehe} trusts Moira, but it would be poor wisdom to divulge more information than is strictly necessary for her operation to run. "So the search goes on."
    *goto nextmoi
*else
    *comment intrigue
    "I asked much of you, Moira. Even as a child, the only times ${they}'d be found is when ${they} [i]wanted[/i] to be."
    
    "You've so much faith in ${them}, Eli," the woman muses. "$!{they} must be quite the character."
    
    "Mm," is the response ${ehe} settles on. $!{ehe} trusts Moira, but it would be poor wisdom to divulge more information than is strictly necessary for her operation to run. "So the search goes on."
    *goto nextmoi

*label nextmoi

Silence hung in the air as the netter gives ${ehim} an edgewise stare, but it's not long before she relents. "You're a terrible bore."

"So I've been told," ${ehe} sniffs. "Apologies that you have to put up with me."

"Words are cheap," the woman drawls in turn, gliding across the room with intent. It does not surprise the traveler one bit that as she climbs into the bed, Moira gently pries open the blanket draped across ${ehis} chest, and trails a finger down the length of ${ehis} sternum. "But I know a way for you to apologize more…[i]convincingly[/i]."

"We have places to be," ${ehe} sighs, the protest laden with the weight of resignation.

"They can wait," Moira replies in turn, strands of hair falling over her face as she pushes ${ehim} down. In a second she's done away with the blankets altogether, the fireplace roaring to life behind her. $!{ehe} feels warmth snaking into the nooks and crannies of the room—incapable of snuffing out the bitter chill, but enough to make existing bearable. Moira guides a leg over ${ehis} stomach and straddles ${ehim}, cherry lips pulled into a playful smirk. "If you are truly opposed to this, now's your chance to say so."

$!{ehe} very nearly does. But there is a blizzard brewing outside, and leagues of snow to traverse before ${ehe} can reach ${yusuha}'s meeting place. $!{ehe} remembers ${ehis} struggle the week prior, when the snow had sunk past the lining of ${ehis} coat, embedding itself upon skin and bone. When ${ehe}'d reached the cottage and borne witness to the lit fireplace, orange-bright and defiant, ${ehe} nearly threw ${ehim}self headfirst into the blaze.

$!{ehis} search, like Noringia, is a cold and barren and barren thing. When a spot of sunlight peeks through the clouds, offering warmth and the promise of brighter days…well, it would be bad manners to refuse.

$!{ehe} runs a hand through ${ehis} hair and stares Moira dead in the eyes. "Do as you like."

The woman smiles as she leans down to devour ${ehim}.

*page_break

Ruinous gales rise all around ${ehim} like a towering wave, its turbulent wails echoing in his head as havoc is wreaked upon the hall. The storm churns and expands like a violent heart, each beat taking a bite out of the masonry and the unfortunate mages. Everywhere ${ehis} eyes turn there is spellfire singing through the air, blinding-bright and violent, lurching desperately for the @{yvar man|woman} with the fox mask. And each time, without fail, they would be met with a surge of wind that parries them away, plunging them into the storm's depths—where they would go to die.

It is far from the first time ${ehe}'s borne witness to ${yusuha}'s trump card, but each encounter with Zephyros still leaves ${ehim} winded as if it were the first time. That such power could be in the hands of any one @{yvar man|woman} seems to be an incredulous thing, a danger beyond comprehension. And while it can be said that ${ehe} is friendly with the red-haired mage, trusts ${yhim} to use ${yhis} powers for good…in the end, ${yhe} is still Tahlia's pawn. $!{yhis} loyalty is a quiet, unsung thing—starkly different from ${falco}'s fierce zeal, but unshakable all the same.

When the winds subside and ${yusuha} signals for ${ehim} to come forward, ${ehe} does so with blade brandished and light gathering at ${ehis} palms. $!{ehis} task is laughably easy, merely to mop up what remains of the broken and disoriented bandits. A stab here, a lance of light there, and soon enough none is left in the hall that could mount a resistance against all-powerful Nightsaber.

($!{ehe} should hate to be on the other end of Nightsaber's wrath, ${ehe} solemnly thinks. An arcanist ${ehe} may be, but where combat is concerned, ${ehe} fears ${ehe} may never catch up with ${yusuha} and ${falco}.)

In the dust-streaked air left behind by Zephyros, ${yusuha} stands tall and solemn, gaze fixed on the far side of the hall. "That should leave their treasury clear," ${ehe} rasps, evidently still winded from casting ${yhis} spell. "Specter, I believe you're up."

"Not coming along?" Specter says, his waves of dark hair a tangled mess in Zephyros's aftermath. "I could use some help decrypting the seals."

"I'd rather not. I'm all spent, you see," the redhead replies. "There's also the possibility that pockets of resistance remains in this cell. If that's so, we'll meet them here and prevent anyone from interrupting your work."

Specter considers the proposal for a moment, before nodding his approval. "Very well. I shall return with good news," he says, before advancing past the corpse-riddled hall to his objective. His steps echo through the room, then fades into the distance.

*page_break $!{ehe} is left alone with the red-headed mage.

"You're up to something, aren't you?" the healer immediately accuses, crossing ${ehis} arms.

${yusuha} cocks ${yhis} head in response, a transparent play at innocence. "What gave you that idea?"

"Specter might not have noticed it because he doesn't get fielded much, but surely you can't expect the same of me," ${ehe} sighs. "I knew you were behaving oddly this entire mission, obsessively checking every nook and cranny for possible hostiles. You've never been nearly this thorough on any of our past missions."

"Perhaps I've turned over a new leaf," ${yusuha} says, waving ${yhis} hand dismissively. "It would be very bad for past enemies to come back and haunt us."

"Then you should be sniffing for hidden threats at the treasury, rather than sending Specter alone into the belly of the beast," ${ehe} points out.

"Perhaps so."

"You [i]wanted[/i] me alone, Fox."

The redhead openly laughs at that. "Oh, let's not jump to conclusions!"

"[i]${yusuha}[/i]."

"Fine, fine," the redhead accedes, throwing ${yhis} hands up in surrender. "It's…I made a [i]discovery[/i] when I left Arcadia. Right around the time you were up north in Noringia."

The healer taps ${ehis} foot impatiently. "A discovery?"

"Mm, if you can call it that," ${yusuha} says. "I was going to submit the Nightsaber reserves list to the [i]ashai[/i] when I chanced upon her…meeting with a guest. As luck would have it, said guest is not unfamiliar to you."

The healer very nearly topples over from shock, and immediately closes the distance towards ${yusuha}. The redhead yelps as ${yhe} feels the other's fingers gripping ${yhis} arms, very nearly summoning a blast of wind in reflex. The healer, overwhelmed with disbelief, barely registers it. "Y-You don't mean…?"

"No, it's not ${fname}—let me go, you brute!" ${yusuha} yells, finally extracting ${yhim}self from the disappointed healer's grasp. "If anything, it's quite the opposite."

"Out with it already," ${ehe} hisses. "I'm in no mood for your games."

"It's Mireil, alright?" ${yusuha} says, carefully gauging ${ehim} for reactions. "Mireil Altinier, shadow queen of Salantira, had been in the [i]ashai[/i]'s office. I believe they might be engaged in some kind of collaboration."

The healer feels ${ehis} heart sink to the ground. $!{ehe} had entreated this possibility on many occasions, but ${ehe}'d chosen to blindly ignore it for fear of hopelessness. The [i]ashai[/i] had thus far been an amicable, if forceful employer, her checkered methods offset by the fact that she is the lone hope of salvation for an oppressed people. Falling into step with her tune had not been easy on ${ehim}, but ${ehe}'s since witnessed firsthand the people the [i]ashai[/i] fights against, their utterly damnable ways—and begins to feel less and less despair for every life ${ehe}'s taken on ${ehis} path.

But to think that the [i]ashai[/i] would consort with ${ehis} murderer…it is a folly greater than ${ehe} can excuse. And not only that—one of the primary reasons ${ehe}'s chosen to lift ${ehis} blade in Arcadia's name is for the resources they possess, the hope of one day reuniting with ${fname}. If Arcadia has both ${ehim} and Mireil in the fold…when Nightsaber unearths ${fname}'s location, to whom will the intel be divulged?

"I see you understand the implications," ${yusuha} says grimly. "I wish it hadn't come to this, but I thought I should let you know all the same."

Somewhere deep down in the pit of ${ehis} stomach, ${ehe} wishes the wind mage wouldn't have told ${ehim}. Not when Tahlia could read ${ehim} like an open book, pick at every last seditious thought brewing in ${ehis} skull. "Were you noticed?" ${ehe} demands, in the end. "Do you think the [i]ashai[/i] expects you to come running to me about it?'

"No, and no," ${yusuha} says. "The [i]ashai[/i] cannot prod around my brain as she pleases, the way she does to the rest of you."

$!{ehe} stares at the wind mage, incredulous. "You've been immune to her powers all this time?"

"Not exactly," ${yusuha} says. "But I cannot tell you any more than this, because whatever information I divulge to you is free pickings for her—not something I'd like to happen, at least for now. But suffice to say that you can be sure this conversation will remain between the two of us." The wind mage's words trail into silence, then, before ${yhe} quietly adds,  "It is also why the [i]ashai[/i] will not know that I advised you to escape her clutches."

"You—huh?"

"'Sweet little Fox, spent from casting Zephyros against an entire bandit cell, could have never predicted that the biggest threat of all came from ${ehis} own ally,'" ${yhe} drawls. "'It is unclear how Plague managed to hide ${ehis} scheme from the [i]ashai's[/i] notice, but the truth remains—${ehe} had backstabbed ${ehis} new allies and rendered their most @{yvar handsome|beautiful} mage unconscious, and taken off into the night.' What do you think? Not bad, huh?"

*temp yufork 0
*label yuyuyu
*choice
    *disable_reuse #"My body is tethered to Tahlia's magic. I'm as good as dead if I defy her."
        *set yufork +1
        "With that spirit, you will be," ${yusuha} sighs. "Listen well: the [i]ashai[/i] will not look kindly upon your betrayal, but she has little reason to kill you for it. You are more useful to her missing than dead. She can threaten you with pain whilst within Arcadia's boundaries—but outside, where dangers lurk at every turn, such occurrences may well lead to your doom. I don't think she'll risk it."
        
        "And just why is it that she's so intent on keeping me alive?"
        
        The redhead shrugs. "I'm just the muscle around here," ${yhe} admits. "But if she's willing to cast [i]aresei[/i] to bring you back, she'll not want to end you at the first turn of your coat. Though I should warn you—if she ever chances upon you again, you would likely not be allowed the same freedoms you currently enjoy."
        
        "[i]If[/i] I get caught," ${ehe} wonders aloud.
        
        "If you've half as talented at hiding as that ${fname} of yours, you'll be fine," ${yusuha} snickers.
        *if (yufork = 1)
            *goto yuyuyu
        *else
            *goto yuyudone
    *disable_reuse #"Why are you telling me all this?"
        *set yufork +1
        "I just want you and your ugly coat out of my sight," ${yusuha} says, and ${ehe} gets the distinct sense that the redhead is [i]winking[/i] at ${yhim}. "It's not like I've made my disdain for it a secret, right?"
        
        The healer has to give it to ${yusuha}—even when the redhead's helping ${ehim} out, ${yhe} never fails to be the most vexatious person alive. "Fine, keep your secrets," ${ehe} sighs. "Jove take me, and Isha too—this will be the most reckless thing I've ever done."
        
        ${yusuha} cocks ${yhis} head dubiously. "Are you sure? I seem to recall that you had sacrificed yourself for—"
        
        "[i]Aside from that[/i]," ${ehe} snaps. Jove alive, why is ${ehe} even justifying ${ehim}self to this knave? "I'll do as you recommend, ${yusuha}. And…thank you."
        
        "Happy to oblige," the redhead replies airily. "You've at least half an hour before Specter comes back from  the treasury. His spirit gates could be bad news, so I'd make tracks if I were you."
        
        The healer silently nods at ${ehis} unexpected ally, before dashing across the hall and out into the open air. A vast expanse of plains stretch out as far as the eye can see, glistening under the shine of starlight. $!{ehe} had dreamed of this moment often, a time when ${ehe} would be free from the shackles to which ${ehe}'d always been confined. First to Thaubal Altinier, then to Salantira, and finally to Tahlia—all these bondages have withered from ${ehis} limbs, and—just as ${ehe}'s always wished—no obstacles stand in ${ehis} way to search for ${fname}.
        
        And yet after so many years of simple, duteous existence, the sprawling road of possibilities only served to terrify. The night air is a touch too cold on ${ehis} skin, the ice-white moon too harsh. $!{ehe} still walks forward despite it all, takes ${ehis} first few steps as a free @{evar man|woman}; and yet the thought still burns like a beacon in ${ehis} mind, immovable, unshakable—
        
        Freedom never felt so oppressive.
        *if (yufork = 1)
            *goto yuyuyu
        *else
            *goto yuyudone

*label yuyudone
*page_break

It is deep into the night when the storm finally breaks, bullets of water bleeding from the gash in the sky. The drifter feels the rain soak through ${ehis} clothes, past the grime and bloodstains tattooed into the fabric. It is just ${ehis} luck, to be caught in the middle of a vicious storm just as ${ehe}'s made it to ${ehis} destination. But such an occurrence is little more than a minor inconvenience for ${ehim} now—${ehe}'s died and come back to life, fought at the behest of ${ehis} murderer's ally, engaged in a fruitless search spanning half of the continent.

It is clear that whatever god presides over Arvanand hold no love of ${ehim}—${ehe} can only rely on ${ehim}self to defy the cruel threads of fate.

Six months have passed since ${ehe} parted ways with Arcadia, and in that time, ${ehe}'s managed a tight balancing act between surviving, evading Arcadia's notice, and investigating ${fname}'s whereabouts. $!{ehis} travels have led ${ehim} as far south as Silcur, through sun-scorched forests and arid wastelands, pursuing the wild-goose trail that's now led ${ehim} back to Salantira. $!{ehe} can't help but feel disdain as ${ehe} stares at Aulain, a town nestled deep in the Salantir heartlands. It is here that the paladin known as Saint Augur lived and died and was put to rest, to be survived by an order that still extols his name, centuries after his passing.

It is here that ${ehe} will scavenge ${ehis} last hope.

*page_break

At the far corner of Aulain is the tomb of Saint Augur, and where many of his paladins have been laid down to rest. It is a defiance of traditional Jovian funeral rites, which called for the bodies to be set afire and sent out to sea. But Saint Augur had many such eccentricities that not even the passage of time could erase, and given the work that his order does in keeping Salantira's peace, the Church is all too happy to look the other way.

$!{ehe} crosses the front's tomb in careful, staggered steps, doing ${ehis} best to avoid the patches of deep mud underfoot. $!{ehis} destination—a night guard's tent set up in the tomb's perimeter—beckons to ${ehim} like a beacon in dark waters. $!{ehe} spies three shadows shifting in its confines, pitch black against the tent's warm orange light, and hears the murmur of voices within. As ${ehe} approaches, the voices seem to heighten in cadence and urgency, and ${ehe} strains to make out the words past the beat of heavy rain.

"Gehanna, there is really no need for such hysterics—"

"She's right, I'm sure you were just hearing things—"

"Jove damn you both, you knaves, I'm the best scout in Salantira, and I know what I heard! Now unhand me, I need to finish the exorcism—wait…is that? By Jove, i-it's right outside!"

The healer pauses just outside the tent flaps as ${ehe} begins to make sense of the conversation—could it be [i]${ehim}[/i] that they're afraid of?—but is given no time at all to process the revelation. $!{ehe} hears the sound of clattering metal over a pair of pained yelps, the telltale noise of bounding footsteps; it is only years of trained combat reflexes that allows ${ehim} to shift ${ehis} weight and lead sideways just enough to avoid the business end of a lance.

"Begone, phantoooom!" ${ehis} assailant cries out, clumsily rotating the spear in her hand to try at a second jab. But the healer, no longer taken by surprise, easily sidesteps her attack, and with one swift draw of ${ehis} blade ${ehe} dispatches the weapon from her trembling hands. Crumpling to her knees, the woman stares at ${ehim} with open horror.

*page_break "Jove keep me, it's an armed phantom…"

"Gehanna!" the woman's companions cry out, blades in hand as they position themselves between Gehanna and the healer. The dark-haired woman of the two, which the healer presumed to be their leader, glares at ${ehim} with disdain. "An assassin, are you? Who sent you? You've a lot of nerve to be attacking the Order of Saint Augur!"

"I mean no harm," the healer vows, sheathing ${ehis} blade in hopes of pacifying the group. "I only sought to defend myself against an unexpected assault."

"Y-You're…human?" Gehanna says from her perch on the ground. "Jove keep us all, we thought you were the dead arisen!"

"'We'? As I recall, you were the only one trying to draw up glyphs for an exorcism," the leader sighs. "Forgive us for not lowering our blades, traveler, but I trust you understand our position. A stranger comes to us in the middle of the night, possessed of a well-used blade and fine-tuned reflexes. Many a traveling group have perished under less conspicuous circumstances."

"Your concern is justified, but I truly mean you no harm," the healer says. "Chief Gruna sent me. I'm told you are in need of a hired blade, and I am in need of an employer."

A disgruntled yelp arises from Gehanna, who has now lifted herself off the ground and dusted off her clothes. "That old codger's gone senile! We're recruiting paladins, not haggard mercenaries!'

"[i]Gehanna[/i]," the man beside her scolds, smacking a knuckle against her head. "Mind your manners. I seem to recall this [i]haggard mercenary[/i] disarmed you with a single swing."

"That's—but that's—it doesn't count!" she whines, shoving the man's chest with force. "I can beat any old warrior to a pulp, but against a [i]ghost[/i] I—"

"[i]Enough[/i]," the leader barks out, and immediately the pair stills into silence. "I apologize for my paladins' conduct, and for the spear Gehanna pointed at your throat. But I can offer you nothing more, for we are not the employers you seek."

$!{ehe} knows that, of course, has known it since the moment ${ehe}'d set foot in this town. Indeed, ${ehe}'d come here in hopes of being drafted into the Order of Saint Augur, and by extension, the church it operates under. All of the traditional options have been exhausted—${ehe}'s seen more netters than ${ehe} can count, has leveraged Tahlia to upturn all the corners of Arvanand—and still ${ehe}'s come up short. With Salantira under Mireil's thrall and Param ruled by a notoriously cautious king, only one avenue is truly left for ${ehim}.

"I will work for food and board, if you will have me," the healer presses, making a show of bowing ${ehis} head in shame. "It's a bad season for beast-hunting, and I haven't been able to find work for the better part of a year. These are desperate times, and if you'd have me point my blade in the name of faith, I will do it—just as long as I can survive."

The three paladins, stunned at ${ehis} proposition, hesitantly glance at one another. In the end, it is Gehanna who breaks the silence. "The order's work is both tedious and dangerous, a far cry from simple beast-hunts," she says. "Are you sure you're up to the task?"

The drifter keeps ${ehis} head bowed, if only to hide ${ehis} smirk. "Are you perhaps interested in testing me?"

"Wh—is that a challenge?" the paladin yells, immediately kicking the grounded spear back into her hands. "Got big in the head just because you dodged a couple of blows, have you? When I wasn't in my right mind, no less!"

"Now, now, Gehanna, let's not get all worked—"

"Shut it, Vas, or you'll be next," Gehanna barks back, prompting the male paladin to sigh and put his hands up in surrender. "Come on, then, let's have a go at it! I'll make sure your lips never flap so loosely again."

The paladins' leader massages her temple and sighs, clearly unamused by her subordinate's antics. "Best two of three," she finally accedes as she steps out into the stormy night. "[i]Practice blows only[/i]. Else I'll be sure to maim the violator myself, am I clear?"

"Crystal," Gehanna hisses, marching away from the group. "I'll show this upstart how it's done."

*page_break

The healer and the paladin both take their places paces from the tent, weapons brandished and stances taut. In the wan light of the shadowed moon, with their sights veiled by the pouring rain, the pair would come to blows and let their steels sing. The healer basks in combat's rhythm and dances to its beat, flowing like a bardsong, swift as a scream.

Six exchanges pass before Gehanna loses her lance, the woman herself sent tumbling across the mud-dark field and crashing into a tree. Dazed but still lucid, she gingerly supports herself back up and stares at the healer in open bewilderment. "I…" she begins, spitting the syllable out with some effort. "It appears I stand corrected."

"I'm glad I could demonstrate my worth," the healer says sagely, turning ${ehis} head in the leader's direction. "Then the first bout is mine?"

"Indeed. And…there will be no need for a second round, I think," Gehanna's leader murmurs vaguely, making no effort at hiding her awe. "You've proven yourself a capable fighter, and we could indeed use someone of your skills."

"Excellent," ${ehe} smiles, affecting gratitude as best as ${ehe} can. "Then you'll have me as a paladin?"

"That we will," the woman replies, reaching a hand out for ${ehim} to shake. The healer shakes the rain from ${ehis} brow and walks forward to meet her halfway. The leader's hand is wet and cold to the touch, but her smile is as warm as any sun.

*page_break

"Welcome," she says, "to the Order of Saint Augur."

*page_break

This is the end of [i]Drift[/i]. Thank you for playing!

*ending
